First you have to get the text from the Blob field. This is done by using streams.

myDemoTable.FIND(’-’);
myDemoTable.CALCFIELDS(BlobField);
myDemoTable.BlobField.CREATEINSTREAM(InStr);
varBigText.READ(InStr);

See also one of my ealier posts about Strings: Strings larger then 250 characters

How do we now use the BigText in a Report? Reports cannot handle a Big Text variable, but a Text variable. So what you have to do is to read parts of the BigText, split it nicely and then fill it into a Text variable, which then can be used.

Ok – let’s look on some details.

Define an Integer DataItem. This is used to handle the run through of the BigText variable.

On the Integer – OnPreDataItem you should set the variable Pos.

Pos := 1

Pos is used to note which starting position you should get Text from.

Now on the AfterGetRecord add the code to handle the Text:

IF Pos > varBigText.Length THEN
  CurrReport.BREAK;

varBigText.GETSUBTEXT(varBigText_as_Text,Pos,100);
varBigText_as_Text := WhereToSplit(varBigText_as_Text, Pos);

GETSUBTEXT returns text to the variable varBigText_as_Text from position Pos and number of characters to return is 100. 100 is the size of my Text variable.

Next we use the function WhereToSplit to get a nicely splitted text, and after this we are ready to use the Text in the Report

I assume you know how to add a Text variable to the Sections of a Report, so will not describe this

The function WhereToSplit looks like this:

i := STRLEN(InText);

IF i = 0 THEN
  EXIT;

WHILE (NOT (InText[i] IN [' ',',','.'])) AND (i > 1) DO
  i -= 1;

Pos += i;

IF i > 0 THEN
  outText := COPYSTR(InText,1,i);

It finds the last space, comma or point and splits the text there.

That’s all – now you can print Big Text in you Report

From Navision 4 it was suddenly possible to handle strings with a length up till 2147483647 characters – this is equivalent to 2 gb. In Navision 4 the data type BigText was introduced.

BigText can only be used for variables (global, local) and not as a field type (in a table). If you need to store a BigText value in a table, then the BigText data must be moved to a BLOB.

BigText can not be displayed in forms, message windows or in the debugger.

To assign text to a BigText variable use the commands ADDTEXT.

varBigText.ADDTEXT(’my text’);
varBigText.ADDTEXT(varMyText);
varBigText.ADDTEXT(varMyText,atPosition);

If no position is omitted, the text will be added to the end of the BigText variable.

To read text from a BigText variable use the command GETSUBTEXT

varBigText.GETSUBTEXT(varText,atPosition,Length) ;

If Length is not ommitted, then the function GETSUBTEXT will retrieve data from the beginning position (atPosition) till the end of the BigText Variable.

The command TEXTPOS, can be used to search for a text in a BigText variable.

atPos := varBigText.TEXTPOS(’my search text’);

This function will often be used in combination with GETSUBTEXT

To get current length of a BigText variable use the command LENGTH.

StrLength := varBigText.LENGTH

To stream a BigText variable into a BLOB use the command WRITE.

varBigText.ADDTEXT(’Text to be stored in a BLOB field ‘);
myDemoTable.BlobField.CREATEOUTSTREAM(outstr);
varBigText.WRITE(outstr);
myDemoTable.INSERT;

To stream a BLOB into a BigText variable use the command READ.

myDemoTable.FIND(’-’);
myDemoTable.CALCFIELDS(BlobField);
myDemoTable.BlobField.CREATEINSTREAM(InStr);
varBigText.READ(InStr);

Now you are able to create functionality which reads entire text files, text streams into BigText variables, perform searches in the BigText variables and store the entire file info in a BLOB field.